OsMA for MetaTrader4

После небольшого перерыва снова вернулся к форексу.

По моим наблюдениям многие используют этот индикатор, т.к. позволяет одним взглядом оценить ситуацию, которую собственно показывает MACD...

В двух словах о нем:
OsMA "Oscillator - Moving Average of Oscillator"
(Осцилятор Скользящего Среднего)
OsMA - в общем случае разность между осцилятором и сглаживанием осцилятора. В данном случае в качестве осцилятора используется основная линия MACD, а в качестве сглаживания - сигнальная линия MACD
Параметры:
1. N - период усреднения для сигнальной линии.
Расчет (на основе MACD):
OsMAj = MACDj - MAvej(MACD, N)

ИНТЕРПРЕТАЦИЯ
Сигнал на покупку дается, когда OsMA перестает снижаться и начинает расти. Сигнал на продажу дается, когда OsMA перестает расти и начинает понижаться. Хороший сигнал дает дивергенция цены и OsMA.

Для простоты использования разукрасим его.
Открываем Метатрейдер, выбираем OsMA, в меню Modify, Заменяем на ниже приведенный текст, компилируем, пользуемся.

Код:

//+------------------------------------------------------------------+
//| OsMA.mq4 |
//| Copyright © 2004, MetaQuotes Software Corp. |
//| v.1.1 |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2008, modify by Faust"
#property link "http://faustforex.blogspot.com/"
//---- indicator settings
#property indicator_separate_window
#property indicator_buffers 2
//#property indicator_color1 Silver
#property indicator_color1 Green
#property indicator_color2 Red
#property indicator_width1 2
#property indicator_width2 2
//---- indicator parameters
extern int FastEMA=12;
extern int SlowEMA=26;
extern int SignalSMA=9;
//---- indicator buffers
double OsmaBuffer1[];
double OsmaBuffer2[];
double MacdBuffer[];
double SignalBuffer[];

//+------------------------------------------------------------------+
//| Custom indicator initialization function |
//+------------------------------------------------------------------+
int init()
{
//---- 2 additional buffers are used for counting.
IndicatorBuffers(4);
//---- drawing settings
SetIndexStyle(0,DRAW_HISTOGRAM);
SetIndexStyle(1,DRAW_HISTOGRAM);

SetIndexDrawBegin(0,SignalSMA);
SetIndexDrawBegin(1,SignalSMA);
IndicatorDigits(Digits+2);
//---- 3 indicator buffers mapping
SetIndexBuffer(0,OsmaBuffer1);
SetIndexBuffer(1,OsmaBuffer2);
SetIndexBuffer(2,MacdBuffer);
SetIndexBuffer(3,SignalBuffer);
//---- name for DataWindow and indicator subwindow label
IndicatorShortName("OsMA("+FastEMA+","+SlowEMA+","+SignalSMA+")");
//---- initialization done
return(0);
}
//+------------------------------------------------------------------+
//| Moving Average of Oscillator |
//+------------------------------------------------------------------+
int start()
{
int limit;
int counted_bars=IndicatorCounted();
//---- last counted bar will be recounted
if(counted_bars>0) counted_bars--;
limit=Bars-counted_bars;
//---- macd counted in the 1-st additional buffer
for(int i=0; i<limit; i++)
MacdBuffer[i]=iMA(NULL,0,FastEMA,0,MODE_EMA,PRICE_CLOSE,i)-iMA(NULL,0,SlowEMA,0,MODE_EMA,PRICE_CLOSE,i);
//---- signal line counted in the 2-nd additional buffer
for(i=0; i<limit; i++)
SignalBuffer[i]=iMAOnArray(MacdBuffer,Bars,SignalSMA,0,MODE_SMA,i);
//---- main loop
for(i=0; i<limit; i++)
{
double current=MacdBuffer[i]-SignalBuffer[i];
double prev=MacdBuffer[i+1]-SignalBuffer[i+1];
if(prev<=current)
{
OsmaBuffer1[i]=current;
OsmaBuffer2[i]=0;
}
else
{
OsmaBuffer2[i]=current;
OsmaBuffer1[i]=0;
}
}
//---- done
return(0);
}
//+------------------------------------------------------------------+